windows Nginx的启动,停止和配置文件修改重启

查看Nginx的版本号:nginx -V

启动Nginx:start nginx

快速停止或关闭Nginx:nginx -s stop   或  taskkill /F /IM nginx.exe > nul

正常停止或关闭Nginx:nginx -s quit

配置文件修改重装载命令:nginx -s reload

查看windows任务管理器下Nginx的进程命令:tasklist /fi "imagename eq nginx.exe"

image

 

nginx.bat

@echo off
rem 当前bat的作用

echo ==================begin========================

cls
SET NGINX_PATH=D:
SET NGINX_DIR=D:\Program Files\nginx-1.2.1\
color 0a
TITLE Nginx 管理程序

CLS

ECHO.
ECHO. * * Nginx 管理程序  * 
ECHO.

:MENU

ECHO. * nginx 进程list * 
tasklist|findstr /i "nginx.exe"

if ERRORLEVEL 1 (echo nginx.exe不存在) else (echo nginx.exe存在)

ECHO.
    ECHO.  [0] 配置文件修改重装载
    ECHO.  [1] 启动Nginx 
    ECHO.  [2] 关闭Nginx 
    ECHO.  [3] 重启Nginx 
    ECHO.  [4] 退 出
ECHO.

ECHO.请输入选择项目的序号:
set /p ID=
    IF "%id%"=="0" GOTO reload
    IF "%id%"=="1" GOTO start
    IF "%id%"=="2" GOTO stop
    IF "%id%"=="3" GOTO restart
    IF "%id%"=="4" EXIT
PAUSE

:reload
    call :reloadNginx
    GOTO MENU

:start
    call :startNginx
    GOTO MENU

:stop
    call :shutdownNginx
    GOTO MENU

:restart
    call :shutdownNginx
    call :startNginx
    GOTO MENU

:reloadNginx
    ECHO.
    ECHO.配置文件修改重装载......
    IF NOT EXIST "%NGINX_DIR%nginx.exe" ECHO "%NGINX_DIR%nginx.exe"不存在

    %NGINX_PATH%

    cd "%NGINX_DIR%"

    IF EXIST "%NGINX_DIR%nginx.exe" (
        echo "reload '' nginx.exe"
        nginx -s reload
    )
    ECHO.OK
    goto :eof
   
:shutdownNginx
    ECHO.
    ECHO.关闭Nginx......
    taskkill /F /IM nginx.exe > nul
    ECHO.OK,关闭所有nginx 进程
    goto :eof

:startNginx
    ECHO.
    ECHO.启动Nginx......
    IF NOT EXIST "%NGINX_DIR%nginx.exe" ECHO "%NGINX_DIR%nginx.exe"不存在

    %NGINX_PATH%

    cd "%NGINX_DIR%"

    IF EXIST "%NGINX_DIR%nginx.exe" (
        echo "start '' nginx.exe"
        start "" nginx.exe
    )
    ECHO.OK
    goto :eof

您可以选择一种方式赞助本站